; MDATE.ASM--
; Create directory MMDDHHMM.SS and cd into it
;
; Make: JWasm -mz mdate.asm
;
	.model	small
	.stack
	.code
start:	mov	ax,cs
	mov	ds,ax
	mov     ah,2Ah	; GET SYSTEM DATE
	int     21h
	mov	di,offset cdate
	mov	al,dh	; DH = month
	call	putval
	mov	al,dl	; DL = day
	call	putval
	mov     ah,2Ch
	int     21h
	mov	al,ch	; CH = hour
	call	putval
	mov	al,cl	; CL = minute
	call	putval
	inc	di
	mov	al,dh	; DH = second
	call	putval
	mov	dx,offset cdate
	mov	ah,39h
	int	21h
	mov	dx,offset cdate
	mov	ah,3Bh
	int	21h
	mov     ax,4C00h
	int     21h
cdate	db 	'00000000.00',0
putval:	aam
	add	ax,3030h
	mov	[di],ah
	inc	di
	mov	[di],al
	inc	di
	ret
	end	start
