WindowTitle {Configuration de la couleur de fond}
WindowSize 430 400		# Taille
WindowPosition 191 15		# Position
ForeColor	{black}
BackColor	{grey85}
ShadowColor	{grey55}
HilightColor	{grey100}
Font		-adobe-helvetica-bold-r-*-*-12-*

Init
 Begin
  WarpPointer 2
  Set $BColor={#009191}
  Set $Lock_Mode={random}
  ChangeValue 4 1
  ChangeValue 5 0
  ChangeBackColor 6 $BColor
  ChangeValue 20 (HexToNum (StrCopy $BColor 2 3))
  ChangeValue 21 (HexToNum (StrCopy $BColor 4 5))
  ChangeValue 22 (HexToNum (StrCopy $BColor 6 7))
 End

PeriodicTasks
 Begin
  Set $MSG=(ReceivFromScript $BROWSER)
  If $MSG <> {No message} Then
  Begin
   ChangeTitle 7 $MSG
   ChangeIcon 8 $MSG
  End
 End

Widget 1
Property
 Size 50 30
 Position 100 360
 Type PushButton
 Title {Appliquer}
Main
 Case message of
  SingleClic :
  Begin
   If (GetValue 5) == 1 Then
    Do {Exec xpmroot } (GetTitle 7)
   Else
    Do {Exec xsetroot -solid "} $BColor {"}
  End
End

Widget 2
Property
 Size 50 30
 Position 190 360
 Type PushButton
 Title {OK}
Main
 Case message of
  SingleClic :
  Begin
   Set $tmp2 = { s noblank}
   # WriteToFile .xinitrc-fvwm {Exec xset s } (GetTitle 14) { } (GetTitle 15) $tmp2
   If (GetValue 5) == 1 Then
   Begin
    Do {Exec xpmroot } (GetTitle 7)
    # WriteToFile .xinitrc-fvwm {xpmroot } (GetTitle 7)
   End
   Else
   Begin
    Do {Exec xsetroot -solid "} $BColor {"}
    # WriteToFile .xinitrc-fvwm {xsetroot -solid "} $BColor {"}
   End
   # WriteToFile .xinitrc-fvwm {xset s } (GetTitle 14) { } (GetTitle 15) $tmp2
  Do {Exec killall -9 FvwmScript} 
  Quit
  End
End

Widget 3
Property
 Size 50 30
 Position 280 360
 Type PushButton
 Title {Annuler}
Main
 Case message of
  SingleClic :
  Begin
   Do {Exec killall -9 FvwmScript}
   Quit
  End
End

Widget 4
Property
 Position 30 30
 Type RadioButton
 Title {Couleur unie:}
 Value 1
Main
 Case message of
  SingleClic :
  Begin
   ChangeValue 5 0 
  End
End

Widget 5
Property
 Position 30 240
 Type RadioButton
 Title {Pixmap:}
 Value 0
Main
 Case message of
  SingleClic :
  Begin
   ChangeValue 4 0 
  End
End

Widget 6
Property
 Size 50 50
 Position 60 80
 Type ItemDraw
 BackColor {#009191}
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 23
Property
 Size 60 60
 Position 55 75
 Type Rectangle
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 24
Property
 Size 50 50
 Position 58 140
 Type ItemDraw
 Title {#009191}
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 20
Property
 Size 250 1
 Position 155 20
 Type HScrollBar
 Value 14
 MinValue 0
 MaxValue 255
Main
 Case message of
  SingleClic :
  Begin
   Set $BColor = {#} (NumToHex (GetValue 20) 2) (NumToHex (GetValue 21) 2) (NumToHex (GetValue 22) 2)
   ChangeTitle 24 $BColor
   ChangeBackColor 6 $BColor
   ChangeValue 4 1 
   ChangeValue 5 0 
  End
End

Widget 21
Property
 Size 250 1
 Position 155 75
 Type HScrollBar
 Value 196
 MinValue 0
 MaxValue 255
Main
 Case message of
  SingleClic :
  Begin
   Set $BColor = {#} (NumToHex (GetValue 20) 2) (NumToHex (GetValue 21) 2) (NumToHex (GetValue 22) 2)
   ChangeTitle 24 $BColor
   ChangeBackColor 6 $BColor
   ChangeValue 4 1 
   ChangeValue 5 0 
  End
End

Widget 22
Property
 Size 250 1
 Position 155 130
 Type HScrollBar
 Value 184
 MinValue 0
 MaxValue 255
Main
 Case message of
  SingleClic :
  Begin
   Set $BColor = {#} (NumToHex (GetValue 20) 2) (NumToHex (GetValue 21) 2) (NumToHex (GetValue 22) 2)
   ChangeTitle 24 $BColor
   ChangeBackColor 6 $BColor
   ChangeValue 4 1 
   ChangeValue 5 0 
  End
End

Widget 7
Property
 Size 280 30
 Position 30 300
 Type TextField
 Title {/usr/share/icons/redhat.xpm}
 Value 200
Main
 Case message of
  SingleClic :
  Begin
   ChangeIcon 8 (GetTitle 7) 
  End
End

Widget 25
Property
 Position 327 299
 Type PushButton
 Title {Selecteur...}
Main
 Case message of
  SingleClic :
  Begin
   Set $ARG={FileBrowser } (GetTitle 7) { Hello word}
   Set $BROWSER=(LaunchScript $ARG )
  End
End

Widget 8
Property
 Size 175 75
 Position 120 215
 Type ItemDraw
 Icon /usr/share/icons/redhat.xpm
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 9
Property
 Size 179 79
 Position 118 213
 Type Rectangle
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 16
Property
 Size 410 330
 Position 10 13
 Type Rectangle
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 18
Property
 Position 15 5
 Type ItemDraw
 Title {Fond}
Main
 Case message of
  SingleClic :
  Begin
  End
End

